delete all

load u:\structs\1MR0.pdb
## - comment out old stuff - load u:\structs\1Y7K.pdb

viewport 600,400
#viewport changes size of all subsequent pictures


select agrp, 1mr0
#select command here, just lets me call pdb file 1MR0 as agrp

hide lines, agrp
#pymol likes to start with 'lines' as the default view shown

color deepteal, agrp
#i like blue better I think.

show cartoon, agrp
#and cartoons make it easy to see the backbone structure

#meat & potatoes
select agrp_disulfides, (resn cys and (name SG or name cb or name ca) and agrp)
#make a new object called 'agrp_disulfides' and fill it with the side chains of the cys residues

color yellow, agrp_disulfides
#should be getting obvious by now

show lines, agrp_disulfides

bg_color white
#sets the background color to white.  Makes better printing. Default is black.

select agrp_pharm, (resi 25-28 and agrp and not (elem h or name c,n,o))
#Here i'm selecting the known pharmacophore - the residues I want to show.
# residues 25-28 (inclusive) but no hydrogens (elem h) or any of the backbone save CA

#fit ( agouti_pharm ), (agrp_pharm )
#fit will take two structures and align them for you

set stick_radius, 0.3

show sticks, agrp_pharm
#hide sticks, elem h and agrp_pharm

color deepteal, (name ca and agrp)
color blue, (elem N and agrp_pharm)

set label_color, black
set label_size, 15
set label_position,(0,2,0)
label (agrp_pharm and n. cz), resn
label (agrp_pharm and n. hz), resn
label (agrp_pharm and n. od1), resn
#label the residues.

set_view (\
     0.234325141,    0.186077118,   -0.954182446,\
     0.043436069,    0.978523493,    0.201491103,\
     0.971188366,   -0.088663228,    0.221212640,\
     0.000011034,   -0.000021160,  -89.958648682,\
     0.146341071,    3.335005522,    1.216003180,\
    65.095748901,  114.821098328,    0.000000000 )
#set_view can be found from the Tcl/Tk window of Pymol.

set antialias=1.0
set depth_cue=0
set ray_trace_fog=0
#typical settings for pretty pictures

ray 600,400
#do ray-tracing.  takes a while but makes the final figure look nice.

#CKP - 18 July 2008