# smase D in ribbons with acitve site plus sulfates and waters
zap
load ../proteins/1XX1.pdb

# Let's play with RASMOL!
# Type "help" to start the help function.
# Type "help commands" to get a list of commands.
# Type "help colors" to get a list of colors.
# Type "help expression" for some hints on how to select things


# RASMOL opens with a wireframe view, so turn it off.
wireframe off

# Let's just work with one of the four molecules in the unit cell.
select *A

# Now get a ribon view.
ribbons on

# The molecule will now rotate funny 'cause of the invisible three.
# So use the center command.
center *A

# We want to color the helices and sheets differently.
# First we have to find out where they are.
# The "structure" command reads the secondary structure assignment out
# of the .pdb file or calculates them if they aren't in the .pdb.
structure

# Now we can pick out the helices and sheets.
# First, the helices:
select helix
color seagreen

# Then the sheets
select sheet 
color YellowTint

# finally everything else
select not(helix or sheet)
color SkyBlue

# I can't live without the stereo...
stereo on

# You can define sets of atoms and give them names.
# This is especially handy if you have subsections of the molecule you 
# need to turn on and off.
# Here, I'm defining groups of atoms in the active site.

# These are the his (12 and 47) and the acid groups (32,34,91)
# catsite = catalytic site
define catsite *A and (12,47,32,34,91)

# hissite is the his groups in the catalytic site
define hissite *A and (12,47)

# metsite is the groups that bind the metals.  
# Ok, so the names aren't very original, so sue me. 
define metsite *A and (32,34,91)

# Now to turn on the metal ion.
# But wait, how did I find it???????
# Type "select hetero" and "cpk"
# All those red spheres are your waters.
# The green sphere tucked away inside the protein is your magnesium.
# Click on the green sphere....
# Bye the way, clicking on any atom will identify it! Hubba hubba
# After you click on the green sphere, you should see:
# Atom: MG  9196  Hetero: MG 9001

# So.....
select MG9001
cpk 
color cpk

# Now, turn on the side chains in the active site.
# "wireframe 75" makes nicely fat wires.  Try other numbers for 
# thinner or fatter wires.
select catsite and sidechain
wireframe 75
color cpk

# The sulfate in the active site is hetero #3001
# I couldn't get it to name properly so:
select hetero and 3001
wireframe 75
color cpk

# Finally, let's get the waters in the active site:
define catwat (HOH931 or HOH927 or HOH890)
select catwat
cpk
color cpk


# Voila!