load ../proteins/1HRC.pdb,main
hide all

show cartoon, all

# make helix, sheet, loop selections so you can use them later
select helix, ss h
select sheet, ss s

# ss l+ selects the heme as well as the loops
# to get the loops alone, you have to exclude the heme (resi 105)
select loops, ss l+ and not resi 105

select backbone = (name ca,c,n,o)
#show sticks, (backbone)


select sidechain, not (name c+n+o)

select met80, sidechain and resi 80
select his18, sidechain and resi 18
select trp59, sidechain and resi 59
select heme = (resi 105)

# turn on the stuff in sticks
show sticks, (heme)
show sticks, (met80)
show sticks, (his18)

# turn on the Trp
show spheres, (trp59)

# this next command colors atoms by a predetermined theme
# you can find the command by turning on the log file and using the menus for color, see Dr. O.
# the carbons in 29 are grey
util.cba(29,"heme")
util.cba(29,"met80")
util.cba(29,"his18")
util.cba(29,"trp59")

#the carbons in 26 are green
#util.cba(26,"heme")

# color the heme iron red
show spheres, (elem Fe)
color red, (elem Fe)

# now color up the secondary structures
color green, (helix and backbone)
# color yellow, (sheet)  # no sheets in cytc!
color skyblue, (loops and backbone)

# this was determined by using the "Get View" command on the menu
set_view (\
     0.282293409,   -0.857938111,   -0.429242194,\
    -0.440143853,   -0.513394535,    0.736681819,\
    -0.852400303,   -0.019034298,   -0.522541344,\
    -0.000154853,    0.000126253, -127.233718872,\
    46.660789490,   23.646203995,    6.274231434,\
   100.312484741,  154.156097412,    0.000000000 )


#ray
#png testing.png

# other commands
# to name chain A
# select chain_A, chain A
# select chain A and resi 100

#select aromatic, resn PHE+TYR+TRP
# select sheet and aromatic
# select sheet or helix

# for printing you can get a white background
bg_color white

# you get better ray tracing if you turn off fog and depth cueing
set depth_cue=0
set ray_trace_fog=0

# crank up the glossiness
# set spec_power = 200
# set spec_refl=1.5